%arg -solver glpk

parameters:
	price[] := (500, 600, 450 );
	costs[] := (425, 520, 400);

	#machine hours required per unit
	a[,] := ((8, 15, 12), (15, 10, 8));

	#upper bounds of the machines
	b[] := (1000, 1000);

	#profit contribution per unit
	{j:=1..count(price[]):  c[j] := price[j]-costs[j]; }

	#upper bound of the products
	xMax[] := (250, 240, 250 );

variables:
	x[1..count(price[])]: integer; 

objectives:
	profit: c[]T  * x[] ->max;

constraints:
	res: a[,] * x[] <= b[];
	0<=x[]<=xMax[];

 
 
 
 
 
